apply plugin: 'com.jfrog.bintray'

apply from: "maven.publish.gradle"

ext {
    projectBintrayDir = "${project.group}/".replace(".", "/") + "${project.name}/${project.version}"
}

bintray {
    user = project.hasProperty('BINTRAY_USER') ? project.property('BINTRAY_USER') : System.getenv('BINTRAY_USER')
    key = project.hasProperty('BINTRAY_KEY') ? project.property('BINTRAY_KEY') : System.getenv('BINTRAY_KEY')
    filesSpec {
        from "${buildDir}/publications/kotlinMultiplatform/"
        include "module.json"
        rename "module\\.json", "${project.name}-${project.version}.module"
        into "${projectBintrayDir}"
    }
    pkg {
        repo = "StandardRepository"
        name = "${project.name}"
        vcsUrl = "https://github.com/InsanusMokrassar/TelegramBotAPI"
        licenses = ["Apache-2.0"]
        version {
            name = "${project.version}"
            released = new Date()
            vcsTag = "${project.version}"
            gpg {
                sign = true
                passphrase = project.hasProperty('signing.gnupg.passphrase') ? project.property('signing.gnupg.passphrase') : System.getenv('signing.gnupg.passphrase')
            }
        }
    }
}

bintrayUpload.doFirst {
    publications = publishing.publications.collect {
        it.name
    }
}

bintrayUpload.dependsOn publishToMavenLocal