krontab/build.gradle

buildscript {
    repositories {
        mavenLocal()
        // jcenter()
        mavenCentral()
        google()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-serialization:$kotlin_version"
        classpath "com.github.breadmoirai:github-release:$github_release_plugin_version"
        classpath "com.getkeepsafe.dexcount:dexcount-gradle-plugin:$dexcount_version"
        classpath "com.android.tools.build:gradle:$android_gradle_version"
    }
}

plugins {
    id "org.jetbrains.kotlin.multiplatform" version "$kotlin_version"
    id "org.jetbrains.kotlin.plugin.serialization" version "$kotlin_version"
    id "org.jetbrains.dokka" version "$dokka_version"
    id "com.gradleup.nmcp.aggregation" version "$nmcp_version"
}

// temporal crutch until legacy tests will be stabled or legacy target will be removed
allprojects {
    if (it != rootProject.findProject("docs")) {
        tasks.whenTaskAdded { task ->
            if(task.name == "jsLegacyBrowserTest" || task.name == "jsLegacyNodeTest") {
                task.enabled = false
            }
        }
    }
}

apply plugin: "com.android.kotlin.multiplatform.library"

project.version = "$version"
project.group = "dev.inmo"

apply from: "publish.gradle"
apply from: "github_release.gradle"


if ((project.hasProperty('SONATYPE_USER') || System.getenv('SONATYPE_USER') != null) && (project.hasProperty('SONATYPE_PASSWORD') || System.getenv('SONATYPE_PASSWORD') != null)) {
    nmcpAggregation {
        centralPortal {
            username = project.hasProperty('SONATYPE_USER') ? project.property('SONATYPE_USER') : System.getenv('SONATYPE_USER')
            password = project.hasProperty('SONATYPE_PASSWORD') ? project.property('SONATYPE_PASSWORD') : System.getenv('SONATYPE_PASSWORD')
            validationTimeout = Duration.ofHours(4)
            publishingType = System.getenv('PUBLISHING_TYPE') != "" ? System.getenv('PUBLISHING_TYPE') : "USER_MANAGED"
        }

        publishAllProjectsProbablyBreakingProjectIsolation()
    }
}

repositories {
    mavenLocal()
    // jcenter()
    mavenCentral()
    // maven { url "https://kotlin.bintray.com/kotlinx" }
    google()
}

apply from: './dokka.gradle'

kotlin {
    jvm()
    js(IR) {
        browser()
        nodejs()
    }
    android {
        compileSdk = "$android_compileSdkVersion".toInteger()
        buildToolsVersion = "$android_buildToolsVersion"
        minSdk = "$android_minSdkVersion".toInteger()
        namespace = "${project.group}.${project.name}"
        compilerOptions.jvmTarget.set(
                compilerOptions.jvmTarget.get().class.fromTarget("17")
        )
        withHostTest {}
    }
    linuxX64()
    mingwX64()
    linuxArm64()
    wasm {
        browser()
        nodejs()
        d8()
    }


    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin('stdlib')
                api "org.jetbrains.kotlinx:kotlinx-coroutines-core:$kotlin_coroutines_version"
                api "org.jetbrains.kotlinx:kotlinx-serialization-core:$kotlin_serialization_version"

                api "com.soywiz.korge:korlibs-time:$klockVersion"
            }
        }

        androidMain {
            dependencies {
                api "androidx.work:work-runtime-ktx:$androidx_work_version"
            }
        }

        commonTest {
            dependencies {
                implementation kotlin('test-common')
                implementation kotlin('test-annotations-common')
                implementation kotlin('test')
                implementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$kotlin_coroutines_version"
            }
        }
        jvmTest {
            dependencies {
                implementation kotlin('test-junit')
            }
        }
        jsTest {
            dependencies {
                implementation kotlin('test-js')
            }
        }
        androidHostTest {
            dependencies {
                implementation kotlin('test-junit')
            }
        }
    }
}

apply plugin: 'com.getkeepsafe.dexcount'

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}