MicroUtils/mppProjectWithSerializationAndCompose.gradle

project.version = "$version"
project.group = "$group"

apply from: "$publishGradlePath"

kotlin {
    jvm {
        compilations.main {
            kotlinOptions {
                jvmTarget = "1.8"
            }
        }
    }
    js (IR) {
        browser()
        nodejs()
    }
    androidTarget {
        publishAllLibraryVariants()
    }

    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin('stdlib')
                api libs.kt.serialization
                implementation compose.runtime
            }
        }
        commonTest {
            dependencies {
                implementation kotlin('test-common')
                implementation kotlin('test-annotations-common')
                implementation libs.kt.coroutines.test
            }
        }
        jvmMain {
            dependencies {
                implementation compose.desktop.currentOs
            }
        }
        jvmTest {
            dependencies {
                implementation kotlin('test-junit')
            }
        }
        jsMain {
            dependencies {
                implementation compose.web.core
            }
        }
        jsTest {
            dependencies {
                implementation kotlin('test-js')
                implementation kotlin('test-junit')
            }
        }
        androidUnitTest {
            dependencies {
                implementation kotlin('test-junit')
                implementation libs.android.test.junit
                implementation libs.android.espresso
            }
        }

        androidMain.dependsOn jvmMain
    }
}

apply from: "$defaultAndroidSettingsPresetPath"

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}


//compose {
//    if (composePluginKotlinVersion != null && !composePluginKotlinVersion.isEmpty()) {
//        kotlinCompilerPlugin.set(composePluginKotlinVersion)
//    }
//}