MicroUtils/gradle/templates/mppJvmJsLinuxMingwProject.gradle

project.version = "$version"
project.group = "$group"

apply from: "$publish"

kotlin {
    jvm {
        compilations.main {
            kotlinOptions {
                jvmTarget = "17"
            }
        }
    }
    js (IR) {
        browser {
            testTask {
                useMocha {
                    timeout = "240000"
                }
            }
        }
        nodejs {
            testTask {
                useMocha {
                    timeout = "240000"
                }
            }
        }
    }
    wasmJs {
        browser()
        nodejs()
    }
    linuxX64()
    mingwX64()

    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin('stdlib')
                api libs.kt.serialization
            }
        }
        commonTest {
            dependencies {
                implementation kotlin('test-common')
                implementation kotlin('test-annotations-common')
                implementation libs.kt.coroutines.test
            }
        }

        jvmTest {
            dependencies {
                implementation kotlin('test-junit')
            }
        }
        jsTest {
            dependencies {
                implementation kotlin('test-js')
            }
        }
        wasmJsTest {
            dependencies {
                implementation kotlin('test-wasm-js')
            }
        }

        nativeMain.dependsOn commonMain
        linuxX64Main.dependsOn nativeMain
        mingwX64Main.dependsOn nativeMain

        androidMain.dependsOn jvmMain
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}